***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Jul 05, 2019                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJA3416-AU   D   G   S
*****param & model definition***
.model  dmos  nmos(
+    l = 1e-6		  w = 1e-6			level = 3
+  vto = 9e-1		 kp = 25			   rb = 1.269e-1)
.model  dds   d(
+   is = 3.076e-09	  n = 1.353			   rs = 3.509e-2
+   eg = 8.022e-1	     trs1 = 7.088e-4)
.model  dbody d(
+   is = 3.076e-09	  n = 1.353			   rs = 3.509e-2
+   eg = 8.022e-1	     trs1 = 7.088e-4
+  cjo = 7.074e-11	  m = 2.777e-1		   vj = 2.336e-2
+   bv = 22			ibv = 250e-6		 tbv1 = 6.227e-4			tt = 25n)
.model  inter  nmos(
+  vto = 0			 kp = 10			level = 1)
.model  dgd   d(
+  cjo = 9.020e-10	  m = 3.977e-1		   vj = 1.000e-2)
.param
+  cgs = 9.787e-10	cgd = 3.503e-10
+   rd = 1.036e-4		 ra = 2.836e-3		  trd = 1.045e-4
*****function & circuit***
rg	  G  1t   1
cgs	 1t   3   {cgs}    ic = 0
egv	 2t   3   table   {v(1t, S)} 
+((0.00 , 0.00 ),
+ (0.50 , 0.50 ), 
+ (1.00 , 1.00 ),
+ (1.50 , 1.40 ),
+ (1.80 , 1.65 ),
+ (2.00 , 1.80 ),
+ (2.50 , 2.10 ),
+ (3.00 , 2.45 ),
+ (4.00 , 2.85 ),
+ (4.50 , 2.95 ),
+ (5.00 , 3.00 ),
+ (6.00 , 3.10 ),
+ (8.00 , 3.20 ),
+ (10.0 , 3.30 ),   
+ (20.0 , 3.40 ),
+ (22.0 , 3.40 ))
egt	  1  2t   value = {6.087e-4*limit(v(2t,3),0,5)*limit((temp-25),-80,125)}
mmain	  2   1   3   3   dmos
rd	  D   4   {rd}    tc = {trd}
dds	  3   4   dds
dbody	  3   D   dbody
ra	  4   2   {ra} 
rs	  3   5   1e-4
ls	  5   S   0.001n 
m1     1t   8   6   6   inter
e1      8   6   4  1t   2
cgd	  7   4   {cgd}   ic = 0
rcgd    7   4   10meg
dgd     6   4   dgd
rdgd    4   6   10meg
m2      7   9  1t  1t   inter
e2      9  1t   4  1t   -2
.ends 
*$
